**Market Value**  
Current\_Value\_Final =

VAR date\_ = SELECTEDVALUE(CalendarDim[Date],MAX(CalendarDim[Date]))

VAR value\_1 =CALCULATE(

    SUM('Dashboard\_Holding'[MarketPrice]),

    FILTER('Dashboard\_Holding',

        'Dashboard\_Holding'[Date]=date\_)

)

RETURN

value\_1

Final\_Current\_Value\_Crs =

 DIVIDE([Current\_Value\_Final],

    10000000,

    0

)  
  
**Previous Month Market Value**  
PM\_Current\_Value\_Final =

VAR PreviousMonthDate =

    CALCULATE(

        MAX(CalendarDim[Date]),

        DATEADD(CalendarDim[Date], -1, MONTH)

    )

VAR DayOfWeek =

    WEEKDAY(PreviousMonthDate, 2) -- Returns 1 for Monday, 7 for Sunday

VAR AdjustedDate =

    SWITCH(

        TRUE(),

        DayOfWeek = 6, PreviousMonthDate - 1, -- If Saturday, move to Friday

        DayOfWeek = 7, PreviousMonthDate - 2, -- If Sunday, move to Friday

        PreviousMonthDate -- Else keep the same date

    )

RETURN

CALCULATE(

    [Current\_Value\_Final],

    CalendarDim[Date] = AdjustedDate

)

**Previous Year Market Value**  
PY\_Current\_Value\_Final =

VAR PreviousYearDate\_ =

    CALCULATE(

        MAX(CalendarDim[Date]),

        DATEADD(CalendarDim[Date], -1, YEAR)

    )

VAR DayOfWeek =

    WEEKDAY(PreviousYearDate\_, 2) -- Returns 1 for Monday, 7 for Sunday

VAR AdjustedDate =

    SWITCH(

        TRUE(),

        DayOfWeek = 6, PreviousYearDate\_ - 1, -- If Saturday, move to Friday

        DayOfWeek = 7, PreviousYearDate\_ - 2, -- If Sunday, move to Friday

        PreviousYearDate\_ -- Else keep the same date

    )

RETURN

CALCULATE(

    [Current\_Value\_New],

    CalendarDim[Date] = AdjustedDate

)

**XIRR%**  
XIRR\_Calculation\_ =

VAR Date\_Modify = MAX(CalendarDim[Date]) -- Get the selected date from the filter context

VAR SelectedDate =

    IF(

        WEEKDAY(Date\_Modify, 2) > 5,

        Date\_Modify - WEEKDAY(Date\_Modify, 2) + 5,

        Date\_Modify

    )

-- Apply filter for valid rows based on Flag and Transaction Date, and exclude "ASK" if after June 3, 2024

VAR FilteredTable\_ =

    FILTER(

        'Dashboard\_Cashflow\_XIRR\_',

        (

            ('Dashboard\_Cashflow\_XIRR\_'[Flag] = 0 && 'Dashboard\_Cashflow\_XIRR\_'[Transaction\_Date] <= SelectedDate)

            ||

            ('Dashboard\_Cashflow\_XIRR\_'[Flag] = 1 && 'Dashboard\_Cashflow\_XIRR\_'[Transaction\_Date] = SelectedDate)

        )

        &&

        (   -- If SelectedDate is after June 3, 2024, exclude "ASK" from Advisor\_Name

            (SelectedDate <= DATE(2024, 07, 03)) ||

            ('Dashboard\_Cashflow\_XIRR\_'[Advisor\_Name] <> "ASK")

        )

    )

-- Calculate XIRR on the filtered table

VAR XIRR\_ =

    IFERROR(

        XIRR(

            SELECTCOLUMNS(FilteredTable\_,

                "Date", 'Dashboard\_Cashflow\_XIRR\_'[Transaction\_Date],

                "Cashflow", 'Dashboard\_Cashflow\_XIRR\_'[Cashflow]

            ),

            [Cashflow],

            [Date]

        ),

        BLANK()

    )

RETURN

IF(

    ISBLANK([test\_holding]),

    BLANK(),

    XIRR\_

)

**Benchmark XIRR% For Nifty 50**

Nifty\_50\_XIRR\_ =

VAR Date\_Modify = MAX(CalendarDim[Date]) -- Get the selected date from the filter context

VAR SelectedDate =

    IF(

        WEEKDAY(Date\_Modify, 2) > 5,

        Date\_Modify - WEEKDAY(Date\_Modify, 2) + 5,

        Date\_Modify

    )

VAR FilteredTable\_ =

    FILTER(

        'Dashboard\_Cashflow\_Benchmark\_XIRR',

        -- Include rows where Flag = 0, or if Flag = 1, only for the selected date

        ('Dashboard\_Cashflow\_Benchmark\_XIRR'[Flag] = 0 && 'Dashboard\_Cashflow\_Benchmark\_XIRR'[Transaction\_Date] <= SelectedDate)

        ||

         ('Dashboard\_Cashflow\_Benchmark\_XIRR'[Flag] = 1 && 'Dashboard\_Cashflow\_Benchmark\_XIRR'[Transaction\_Date] = SelectedDate)

    )

RETURN

VAR xirr\_ =  IFERROR(XIRR(

        SELECTCOLUMNS(

            FilteredTable\_,

             "Date", 'Dashboard\_Cashflow\_Benchmark\_XIRR'[Transaction\_Date],

             "Cashflow", 'Dashboard\_Cashflow\_Benchmark\_XIRR'[Nifty50Cashflow]),

        [Cashflow],

        [Date]

    ),BLANK()

    )

RETURN

IF (

    ISBLANK([test\_holding]),

    BLANK(),

    xirr\_

    )  
  
\*Change Cashflow column for respective Index  
  
Benchmark\_XIRR\_Summary =

SWITCH(

    TRUE(),

    SELECTEDVALUE(Index\_Selection[Index]) = "Nifty 50", [Nifty\_50\_XIRR\_],

    SELECTEDVALUE(Index\_Selection[Index]) = "Nifty 100", [Nifty\_100\_XIRR\_],

    SELECTEDVALUE(Index\_Selection[Index]) = "Nifty 200", [Nifty\_200\_XIRR\_],

    SELECTEDVALUE(Index\_Selection[Index]) = "Nifty 50 TRI", [Nifty\_50\_TRI\_XIRR\_],

    SELECTEDVALUE(Index\_Selection[Index]) = "Nifty 500", [Nifty\_500\_XIRR\_],

    SELECTEDVALUE(Index\_Selection[Index]) = "Nifty 500 TRI", [Nifty\_500\_TRI\_XIRR\_],

    SELECTEDVALUE(Index\_Selection[Index]) = "BSE 100", [BSE\_100\_XIRR\_],

    SELECTEDVALUE(Index\_Selection[Index]) = "BSE 200", [BSE\_200\_XIRR\_],

    SELECTEDVALUE(Index\_Selection[Index]) = "BSE Sensex", [BSE\_Sensex\_XIRR\_],

    SELECTEDVALUE(Index\_Selection[Index]) = "BSE 500 TRI", [BSE\_500\_TRI\_XIRR\_],

    SELECTEDVALUE(Index\_Selection[Index]) = "Sensex TRI", [Sensex\_TRI\_XIRR\_],

    SELECTEDVALUE(Index\_Selection[Index]) = "BSE 500", [BSE\_500\_XIRR\_],

    BLANK()

)

**MoM %**

Final\_MoM\_CMV =

VAR value\_1 = DIVIDE(

    [Current\_Value\_New]-[PM\_Current\_Value\_Final],

    [PM\_Current\_Value\_Final],

    0)

RETURN

IF(

    ISBLANK([test\_holding]),

    BLANK(),

    value\_1

)

**YoY %**

Final\_YoY\_CMV =

VAR value\_1 =

DIVIDE(

   [Current\_Value\_New]-[PY\_Current\_Value\_Final],

   [PY\_Current\_Value\_Final],

   0)

VAR HoldingCostBlank = ISBLANK([Holding\_Cost\_New])

RETURN

IF(

    HoldingCostBlank,

    BLANK(),

    value\_1

)

**Holding Period**

Holding\_Period =

VAR Start\_Date = MIN(Dashboard\_Cashflow\_XIRR\_[Transaction\_Date])

VAR End\_Date = SELECTEDVALUE(CalendarDim[Date], MAX(CalendarDim[Date]))

VAR TotalDays = DATEDIFF(Start\_Date, End\_Date, DAY)

VAR TotalYearsDecimal = ROUND(TotalDays / 365, 1) -- Calculate years as a decimal with 1 decimal place

VAR Final\_Value = TotalYearsDecimal & " yrs" -- Combine the decimal value with " yrs"

VAR BlanksRemoved =

    IF(

        ISBLANK([Holding\_Cost\_New]),

        BLANK(),

        Final\_Value

    )

RETURN

IF(

    ISINSCOPE(test\_mapping[Advisor\_Name]) && SELECTEDVALUE(test\_mapping[Mapping\_Key]) <> "Direct-Mutual Fund-Equity-Mutual Fund",

    BlanksRemoved,

    BLANK()

)

**Cashflow**

Cashflow\_FTM =

VAR SelectedDate = MAX(CalendarDim[Date]) -- Get the selected date from the filter context

VAR StartOfMonth\_ = DATE(YEAR(SelectedDate), MONTH(SelectedDate), 1) -- First day of the selected month

VAR FilteredTable\_ =

    FILTER(

        'Dashboard\_Cashflow\_XIRR\_',

        (

            'Dashboard\_Cashflow\_XIRR\_'[Flag] = 0

        ) &&

        'Dashboard\_Cashflow\_XIRR\_'[Transaction\_Date] >= StartOfMonth\_ &&

        'Dashboard\_Cashflow\_XIRR\_'[Transaction\_Date] <= SelectedDate

    )

VAR TotalCashflow =

    SUMX(

        FilteredTable\_,

        'Dashboard\_Cashflow\_XIRR\_'[Cashflow]

    )

RETURN

IF(

    ISBLANK(TotalCashflow),

    "-",

    DIVIDE(TotalCashflow, 10000000, 0)

)